Dim numCorrect As Integer
Dim numIncorrect As Integer
Dim userName As String
Dim qAnswered() As Boolean

Sub GetStarted()
    Initialize
    YourName
    ActivePresentation.SlideShowWindow.View.Next
End Sub

Sub Initialize()
    Dim i As Long
    Dim numQuestions As Long
    
    numCorrect = 0
    numIncorrect = 0
    numQuestions = ActivePresentation.Slides.Count - 2
    ReDim qAnswered(numQuestions)
    For i = 1 To numQuestions
        qAnswered(i) = False
    Next i
End Sub

Sub YourName()
    userName = InputBox(Prompt:="Type your name")
End Sub

Sub RightAnswer()
    Dim thisQuestionNum As Long

    thisQuestionNum = _
        ActivePresentation.SlideShowWindow.View.Slide.SlideIndex - 1
    If qAnswered(thisQuestionNum) = False Then
        numCorrect = numCorrect + 1
    End If
    qAnswered(thisQuestionNum) = True
    DoingWell
End Sub

Sub WrongAnswer()
    Dim thisQuestionNum As Long

    thisQuestionNum = _
        ActivePresentation.SlideShowWindow.View.Slide.SlideIndex - 1
    If qAnswered(thisQuestionNum) = False Then
        numIncorrect = numIncorrect + 1
    End If
    qAnswered(thisQuestionNum) = True
    DoingPoorly
End Sub

Sub DoingWell()
    MsgBox ("You are doing well, " & userName)
End Sub

Sub DoingPoorly()
    MsgBox ("Try to do better next time, " & userName)
End Sub

Sub Feedback()
    MsgBox ("You got " & numCorrect & " out of " _
        & numCorrect + numIncorrect & ", " & userName)
End Sub

'Copy and paste this procedure to make other short-answer questions.
'Change the name of the procedure, change the text of the question, and
'change the text of the correct answer.  Change no other VBA.
Sub Question7()
    Dim answer
    
    answer = InputBox(Prompt:="What is the capital of Maryland?", _
        Title:="Question 7")
    If answer = "Annapolis" Then
        RightAnswer
    Else
        WrongAnswer
    End If
End Sub