Dim numCorrect As Integer
Dim numIncorrect As Integer
Dim userName As String
Dim qAnswered As Boolean

Sub GetStarted()
    Initialize
    YourName
    RestoreState 'ADDED
End Sub

Sub Initialize()
    numCorrect = 0
    numIncorrect = 0
    qAnswered = False
End Sub

Sub YourName()
    userName = InputBox("Type your name")
End Sub

Sub SaveState() 'ADDED
    ActivePresentation.Tags.Add "current slide", _
        ActivePresentation.SlideShowWindow.View.Slide.SlideIndex
    ActivePresentation.Tags.Add "number correct", numCorrect
    ActivePresentation.Tags.Add "number incorrect", numIncorrect
    ActivePresentation.Save
End Sub

Sub ClearState() 'ADDED
    ActivePresentation.Tags.Delete "current slide"
End Sub

Sub RestoreState() 'ADDED
    Dim keepGoing As Long
    
    If ActivePresentation.Tags("current slide") = "" Then
        'Nothing is saved. Just go to the next slide.
        ActivePresentation.SlideShowWindow.View.Next
    Else
        keepGoing = MsgBox("Do you want to pick up where you left off?", vbYesNo)
        If keepGoing = vbNo Then
            'User said no. Start over.
            ClearState
            ActivePresentation.SlideShowWindow.View.Next
        Else
            'User said yes. Continue where user left off.
            ActivePresentation.SlideShowWindow.View.GotoSlide _
                ActivePresentation.Tags("current slide")
            numCorrect = ActivePresentation.Tags("number correct")
            numIncorrect = ActivePresentation.Tags("number incorrect")
        End If
    End If
End Sub

Sub RightAnswer()
    If qAnswered = False Then
        numCorrect = numCorrect + 1
    End If
    qAnswered = False
    MsgBox "You are doing well, " & userName
    ActivePresentation.SlideShowWindow.View.Next
    SaveState 'ADDED
End Sub

Sub WrongAnswer()
    If qAnswered = False Then
        numIncorrect = numIncorrect + 1
    End If
    qAnswered = True
    MsgBox "Try to do better next time, " & userName
End Sub

Sub Question3()
    Dim answer As String
    
    answer = InputBox(Prompt:="What is the capital of Maryland?", _
    Title:="Question 3")
    answer = Trim(answer)
    answer = LCase(answer)
    If answer = "annapolis" Or _
        answer = "anapolis" Or _
        answer = "annappolis" Or _
        answer = "anappolis" Then
        RightAnswer
    Else
        WrongAnswer
    End If
End Sub

Sub Feedback()
    MsgBox "You got " & numCorrect & " out of " _
        & numCorrect + numIncorrect & ", " & userName
    ClearState 'ADDED
    ActivePresentation.SlideShowWindow.View.GotoSlide 1 'ADDED
End Sub